<!-- #include file="includes/variables-inc.asp" -->
<!-- #include file="includes/manager-inc.asp" -->
<!-- #include file="includes/sessions-inc.asp" -->
<!-- #include file="includes/database-inc.asp" -->
<!-- #include file="includes/consts-inc.asp" -->
<!-- #include file="includes/configuration-inc.asp" -->
<!-- #include file="includes/functions-inc.asp" -->
<!-- #include file="includes/imgsz-inc.asp" -->
<!-- #include file="includes/cls_upload-inc.asp" -->
<%
Dim Uploader, File, sAllowExt, este
Dim sReferrer, i, fso, sUpPath, aRes, sMaxFileSize
Dim lngWidth, lngHeight, lngDepth, strImageType
Dim sUploadFolder, sResUp, sUploadFile, UpTempFileName
Dim sTempUpPath


sMaxFileSize = "" & Session("MaxFileSize")

sAllowExt = "" & Session("AllowExt")
if trim(sAllowExt) = "" or lcase(sAllowExt) = "default" then
	if IsAuthorizedBin(ROLE_ADMINISTRATOR) then
		sAllowExt = imgExtensions & ", *.*, " & allowedExtensions
	else
		sAllowExt = imgExtensions & ", " & allowedExtensions
	end if
end if
'security referrer control
sReferrer = Request.ServerVariables("HTTP_REFERER")
If left(sReferrer, len(GLOBAL_SITE_URL & GLOBAL_SITE_PATH)) = GLOBAL_SITE_URL & GLOBAL_SITE_PATH Then
	Set Uploader = New FileUploader

	Uploader.maxSize = 2 * iMaxSize
	if IsNumeric(sMaxFileSize) then
		Uploader.maxFileSize = Clng(sMaxFileSize)
	else
		Uploader.maxFileSize = iMaxSize
	end if
	Uploader.fileExt = sAllowExt
	Uploader.maxBuffer = 4096
	Uploader.Upload()
	If Uploader.Files.Count = 0 Then
		If Uploader.errors Then
			aRes = split(Uploader.errorDesc, "|")
			sResUp = aRes(3)
			sUploadFile = aRes(1)
		End If
	Else
		If Uploader.errors Then
			aRes = split(Uploader.errorDesc, "|")
			sResUp = aRes(3)
			sUploadFile = aRes(1)
		End If
		sUploadFolder = "" & Session("UploadFolder")
		sUpPath = Server.MapPath(sUploadFolder)
		For Each File In Uploader.Files.Items
			Set fso = CreateObject("Scripting.FileSystemObject")
			'
			UpTempFileName = File.FileName
			'
			sUploadFile = "" & Session("UploadFile")
			if trim(sUploadFile) <> "" then
				if UpTempFileName <> sUploadFile then
					File.OverWrite = True
					File.FileNameShort = fso.GetBaseName(sUploadFile)
					'clean original name
					UpTempFileName = cleanFileName(UpTempFileName, 0)
					'if original extension is valid
					este = fso.GetExtensionName(UpTempFileName)
					if trim(este) <> "" and instr(sAllowExt, "*." & este) > 0 Then
						File.FileName = fso.GetBaseName(sUploadFile) & "." & este
						File.FileExt = este
					else
						File.FileName = fso.GetFileName(sUploadFile)
						File.FileExt = fso.GetExtensionName(sUploadFile)
					end if
				end if
			else
				sUploadFile = cleanFileName(UpTempFileName, 0)
				if UpTempFileName <> sUploadFile then
					File.OverWrite = True
					File.FileNameShort = fso.GetBaseName(sUploadFile)    'nome senza estensione
					File.FileName = fso.GetFileName(sUploadFile)         'nome completo
					File.FileExt = fso.GetExtensionName(sUploadFile)     'estensione
				end if
			end if
			'
			'Save file
			File.SaveToDisk sUpPath
			sUploadFile = File.FileName
			sTempUpPath = sUpPath
			'
			sResUp = "9"
			'
			este = fso.GetExtensionName(sUploadFile)
			If len(este) > 0 Then
				'if it is an image, verify if it is correct
				If instr(imgExtensions, "*." & lcase(este)) > 0 Then
					If gfxSpex(sUpPath & "\" & sUploadFile, lngWidth, lngHeight, lngDepth, strImageType) Then
						If lcase(este) <> lcase(strImageType) Then
							If fso.FileExists(sUpPath & "\" & sUploadFile) Then
								fso.DeleteFile(sUpPath & "\" & sUploadFile)
							end if
							sResUp = "8"
						end if
					else
						If fso.FileExists(sUpPath & "\" & sUploadFile) Then
							fso.DeleteFile(sUpPath & "\" & sUploadFile)
						end if
						sResUp = "8" 'sTempUpPath & "\" & sUploadFile
					end if
				end if
			else
				sResUp = "8"
			end if
			Set fso = Nothing
		Next
	End If

	on error resume next
	Session.Contents.remove("UploadFile")
	If Err <> 0 Then
		Err.Clear
		Session("UploadFile") = ""
	End If
	On Error Goto 0

	on error resume next
	Session.Contents.remove("MaxFileSize")
	If Err <> 0 Then
		Err.Clear
		Session("MaxFileSize") = ""
	End If
	On Error Goto 0

	on error resume next
	Session.Contents.remove("AllowExt")
	If Err <> 0 Then
		Err.Clear
		Session("AllowExt") = ""
	End If
	On Error Goto 0

	i = instr(sReferrer, "?")
	if i > 0 then
		sReferrer = left(sReferrer, i - 1)
	end if
	ReleaseObjects
	Response.Redirect sReferrer & "?act=" & sResUp & "&fil=" & sUploadFile
	Response.end
End If
%>